Access a specific resultset (Query) row

[vernade]

I am iterating over a CF Query and want to implement a generic function which
takes the query and the rownumber as a parameter. How can I access a specific
row in a CF Query Object and retrieve the complete row as struct?

Are there any functions on CF Query objects which I can access.

A requirement is that I do not change the cursor (CurrentRow) while iterating
over the query and retrieving the data.

[mxstu]

As far as I know there are no CF functions that return an entire query row as a
structure, but you can create your own function. Just pass in a query object
and a row number and the function uses the query.columnList to add the column
values for the current row to the returned structure.



<!--- return selected query row as a structure --->
<cfscript>
function GetQueryRow(query, rowNumber) {
var i = 0;
var rowData = StructNew();
var cols = ListToArray(query.columnList);
for (i = 1; i lte ArrayLen(cols); i = i + 1) {
rowData[cols[i]] = query[cols[i]][rowNumber];
}
return rowData;
}
</cfscript>

<cfoutput query="yourQuery">
<cfset theCurrentRow = GetQueryRow(yourQuery, currentRow)>
<cfdump var="#theCurrentRow#">
</cfoutput>

[vernade]

Thank you for your response... this was exactly the solution I was looking for.
I did not realize that you can access a query object with brackets, like
query[column][row].

The CF documentation either misses this point or I was not able to find it.

[Rachel]

You can use a query of a query to do this too:

<cfquery name="myQueryRow" dbtype="query">
SELECT * FROM myOtherQuery WHERE id=id_of_row
</cfquery>

Then myQueryRow will only have the row you're selecting, as a query object of its own.

[Matt]

I tried several approaches, none of them worked for me except this one:

queryName.field_name[rowNumber]

Can use the queryName.currentrow property to get the current row number and then just add one to it to get your rowNumber