Access Query in ASP

[Ambassador]

I would like to use Accesss queries in ASP. This queries are done
before in Access. I Know that i can access these queries using Visual
Basic as below

'****************************
Sub RunAccMacro()
Dim oAccess as Object, oDB as Object
Set oAccess = CreateObject("Access.Application")
oAccess.Visible = True
oAccess.OpenCurrentDatabase "C:\DB1.mdb"
oAccess.Run "MyAccessMacro"
End Sub
'***************************


I got this code from msdn.com
is it possible to do same thing by ASP. if possiblle i need sample.

Thank you.

[Bob Barrows]

Ambassador wrote:

> I would like to use Accesss queries in ASP. This queries are done
> before in Access. I Know that i can access these queries using Visual
> Basic as below
>
> '****************************
> Sub RunAccMacro()
> Dim oAccess as Object, oDB as Object
> Set oAccess = CreateObject("Access.Application")
> oAccess.Visible = True
> oAccess.OpenCurrentDatabase "C:\DB1.mdb"
> oAccess.Run "MyAccessMacro"
> End Sub
> '***************************

This is code to run a macro. Are you asking how to run a macro or a saved
query?


Here's an example for running a saved query. There are other ways, but I
like this the best:

For a saved action query (no records returned) called qryHotels:
'Open a connection
set cn=server.createobject("adodb.connection")
cn.open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=DB1.mdb"
cn.qryHotels
cn.close: set cn=nothing

'For a saved query that returns records:

'Open a connection
set cn=server.createobject("adodb.connection")
cn.open "Provider=Microsoft.Jet.OLEDB.4.0;" & _
"Data Source=DB1.mdb"
set rs=server.createobject("adodb.recordset")
cn.qryHotels rs
if rs.eof then
response.write "No records were returned"
else
'write the results to a table:
Response.Write "<table border=1><tr><td>"
sHTML=rs.GetString(2,,"</td><td>", _
"</td></tr><tr><td>","NA")
sHTML = Left(sHTML, len(sHTML) - 8)
response.Write sHTML
response.write "</table>"
end if
rs.close: set rs=nothing
cn.close: set cn=nothing

If your saved query takes parameters:

cn.qryHotels parmval1, ..., parmvalN

or

set rs=server.createobject("adodb.recordset")
cn.qryHotels parmval1, ..., parmvalN, rs


HTH,
Bob Barrows
--
Microsoft MVP - ASP/ASP.NET
Please reply to the newsgroup. This email account is my spam trap so I
don't check it very often. If you must reply off-line, then remove the
"NO SPAM"

[Bullschmidt]

You can access a query (assuming no parameters) just like a table in
ASP.

And this works for a SQL statement:
strSQL = "SELECT * FROM MyQuery"

Best regards,
J. Paul Schmidt, Freelance ASP Web Developer
[url]http://www.Bullschmidt.com[/url]
ASP Design Tips, ASP Web Database Demo, Free ASP Bar Chart Tool...


*** Sent via Developersdex [url]http://www.developersdex.com[/url] ***
Don't just participate in USENET...get rewarded for it!