Different resolutions

[subigor]

I created a project that is a mix of old ones, in a way that I have some dir
movies at 800x600 and other dir movies to 1920x1200. I put them in a cd rom and
now the problem is that if someone has a lower resolution than 1920x1200 he
won't see everything. Is there a way to make all movies apear the same size, or
change the final user screen resolution. I tryed BuddyApi, but to be honest I
don't understand what command I have to use or in wich way to use it.

Thanks!

[klgc]

Just replied to a resolution question earlier today, but here it is again. I
have tried many of the resolution xtras and stand alones available and have
found just about all of the ones I tried mess up the viewers screen. I mean
that in restoring the viewers screen, their desktop is rearranged.

Then I tried the AndradeArts "resolution" xtra and found the results better
than anything else I have tried. It even controls process switching which can
screw up a movie with MIAWs. Anyway, if you are using MX2004 be sure to get
the new version (the one on the MX2004 CD).

If you need an example of how I use it (the Lingo), I could send you a text
file of the code. I do a little more than the author's sample.

PS. If it needs to be said - I have no relationship with AndradeArts.

[subigor]

Thanks for the answer! it would be great if you could send me the Lingo code so I can test it. Then I will tell you about.

[klgc]

Following is the Lingo I use:

Resolution Xtra coding extracted from movie script

-----------------------------------------------------------------

global gResXtra, gScrSettings

-----------------------------------------------------------------
on prepareMovie

if the runmode = "Projector" then

-- initialize resolution Xtra
gResXtra = new(Xtra "resolution", "xxxxxx-xxxxx-xxxxx-xxxxx")

-- initialize desired screen settings
-- (width, height, depth, and changed flag)
gScrSettings = [1024, 768, 32, 0]

-- find best available screen resolution (at or above desired)
scrList = get_display_modes(gResXtra)
tw = 9999
th = 9999
td = 0
repeat with i = 1 to scrList.count
if ((scrList[i][1] = gScrSettings[1]) \
AND (scrList[i][2] >= gScrSettings[2])) \
OR ((scrList[i][1] >= gScrSettings[1]) \
AND (scrList[i][2] = gScrSettings[2])) then
if (scrList[i][1] <= tw) AND (scrList[i][2] <= th) \
AND (scrList[i][3] >= td) then
tw = scrList[i][1]
th = scrList[i][2]
td = scrList[i][3]
end if
end if
end repeat
gScrSettings[1] = tw
gScrSettings[2] = th

-- test best available screen resolution (at or above desired)
-- and minimum desired color depth to see if display mode can
-- be set to such
scrTest = test_resolution(gResXtra, gScrSettings[1], \
gScrSettings[2], gScrSettings[3])
if NOT scrTest then
alert "Sorry, your monitor can not be temporarily set at " \
& "or above a minimum of 1024x768 and 32 bit color"
halt
end if

-- OK to initiate new settings
-- change screen resolution and color if other than desired
scrAt = get_current_display_mode(gResXtra)
if (gScrSettings[1] <> scrAt[1]) OR \
(gScrSettings[2] <> scrAt[2]) OR \
(gScrSettings[3] > scrAt[3]) then
gScrSettings[4] = 1 -- flag change
t = set_resolution(gResXtra, gScrSettings[1], \
gScrSettings[2], gScrSettings[3])
center_stage(gResXtra)
end if

-- clear monitor and prevent control task switching
hide_taskbar(gResXtra)
hide_desktop(gResXtra, 0, 0, 0)
set_auto_switching(gResXtra, 0)
disable_task_switching(gResXtra)

end if

(other movie initialization coding)

end prepareMovie

-----------------------------------------------------------------
-----------------------------------------------------------------
on stopMovie

if the runmode = "Projector" then

-- restore display mode
if gScrSettings[4] then
reset_resolution(gResXtra)
end if

-- restore task switching
enable_task_switching(gResXtra)
set_auto_switching(gResXtra, 1)

-- restore desktop
show_desktop(gResXtra)
show_taskbar(gResXtra)

-- kill the xtra reference
gResXtra = 0

end if

end stopMovie

-----------------------------------------------------------------

[subigor]

Thanks mate! I hope this one works. I'll tell you about.