Editing too many markers, How?

[King Jeremy]

Is there a better way to edit (add, name) markers to a score, assuming a
case like too many markers (let's say over 1000), consecutive named (ie.
link####) and located like one in every five frames.

[Darrel Hoffman]

> Is there a better way to edit (add, name) markers to a score, assuming a

> case like too many markers (let's say over 1000), consecutive named (ie.
> link####) and located like one in every five frames.

Hmm. According to the Director help files, the markerList can be tested, but not set. It seems there may not be a way to create
markers through lingo, only manually. However, nothing is stopping you from making your own marker list. Just create a global
list, like so:

global myMarkers
myMarkers = [5, 10, 15, etc]

Then you can use this as if it were a marker by saying:

go myMarkers[2]

[JB]

the Markers window is a handy place to edit a series of markers

to di it with lingo, perhaps inside of a custom movie in a widow utility

the markerlist reports the frame and name of each marker, this is read
only

one way to change a marker name in lingo

go to a frame containing a merker

set the frameLabel = "somename"


you couldtemporarily place a couple of interface buttons and an entry
field on stage that coulod edit markers rather then attempting to cursor
around the tough to edit score markes.

-- advance button script
on mouseup
go next
put the frameLabel into field "labeledit"
end

-- submit change button script
on mouseup
set the frameLabel =v field "labeledit"
end

[JB]

oh yea, and remember you can magnify the score with controls on the
ight side, so the marker names don't overlap and are easier to edit.

[Mark A. Boyd]

On 10 Oct 2003, "King Jeremy" <victim_666@hotmail.com> wrote:

> Is there a better way to edit (add, name) markers to a score, assuming a
> case like too many markers (let's say over 1000), consecutive named (ie.
> link####) and located like one in every five frames.

I haven't used these in a long time, but they're still in my library.

on reLabel howMany, baseName
myFrame = the frame
rpt = ""
repeat with i = 1 to howMany
go to marker(1)
beginRecording
set the frameLabel = baseName &pad(4,i)
endRecording
end repeat
go to myFrame
end

on makeLabels numFrames, baseName, sep
if numFrames.voidP then
put "Usage: makeLables(numFrames, baseName, sep)"
return
end if
if sep.voidP then sep = 4
myFrame = the frame
go to marker(0)
tmpFrame = the frame
repeat with i = 1 to numFrames
beginRecording
go to the frame + sep
set the frameLabel = baseName &pad(4,i)
endRecording
end repeat
go to myFrame
end

on pad howMany, inString, padChar
if howMany.voidP or inString.voidP then
alert "Usage: Pad (howMany, InString, [padChar])" &RETURN &RETURN
&"padChar defaults to 0"
else
if padChar.voidP then padChar = 0
tmp = EMPTY
numChars = howMany - string(inString).chars.count
repeat with i = 1 to numChars
tmp = tmp &padChar
end repeat
return tmp &inString
end if
end


The movie does not have to be playing for these to work. To create the
labels, use makeLabels.

makeLabels 10,"xxx_"

The above will create 10 markers 5 frames apart beginning with "xxx_0001"

To rename them, use reLabel

relabel 10, "yyy_"

I could swear I had a version that allowed you to define the beginning and
ending frames as parameters, especially for reLabel. I guess that didn't
get archived. You can modify these or just make sure your playback head is
on the frame you want to start with (or the marker before???).


--
Mark A. Boyd
Keep-On-Learnin' :)

[King Jeremy]

I didn't get how to apply these scripts.

[Mark A. Boyd]

On 12 Oct 2003, "King Jeremy" <victim_666@hotmail.com> wrote:

> I didn't get how to apply these scripts.

Put them all in a movie script. Then use the message window to execute
one of them.

So, if you want to create 100 markers, 5 frames apart, named "myMarker_
0001", "myMarker_0002", "myMarker_0003", ...

-- Welcome to Director --
makeLabels(100,"myMarker_")

Try it in a new, empty movie to see how it works.

The makeLabels script expects at least one parameter, numFrames. This is
an integer indicating how many markers you want to create. You can
optionally supply the baseName parameter which will be appended with a
number. If you do not supply that parameter, the frames will be named
"0001", "0002", etc.

ReLabel works pretty much the same way, but I apparently named the first
parameter as howMany. Again, this tells the script how many markers you
want to rename.

The pad script is what inserts a given number of 0's in order to "pad"
the number with 0's. Since you mentioned that you may have 1000's of
markers, I chose to pad the numbers to 4 places:

set the frameLabel = baseName &pad(4,i)

You don't have to use that part if you don't want to. I just prefer
padding the numbers with 0's due to how computers sort strings: "1",
"10", "11", "12", "13", "14", "15", "16", "17", "18", "19", "2", "20",
"21", ...

If you prefer not padding the numbers, just use

set the frameLabel = baseName &i

As I said, they're quite old. They were written for a single use and I
never really bothered to make them user friendly. I'm sure they have lots
of room for improvement and error checking. If they're not useable as is
in your situation, they should at least illustrate the commands/functions
used and it should be easy enough to create your own.



--
Mark A. Boyd
Keep-On-Learnin' :)

[King Jeremy]

Finally I got it and really great thanks for these scripts.
This was exactly what I needed.