Help creating randomly falling sprites with lingo

[Word of Mouth Productions]

Attach the following behavior to each sprite that's to fall. Adjust the
pSpeed parameter to make the objects fall faster or slower. Adjust the
pInterval to determine how long an object waits at the top of the screen
before it starts falling. The setting of the locH is restricted to the width
of the stage so you might want to change that in the two places it's done if
you want the objects falling within a certain range of the stage other than
the whole stage.

property pS, spriteNum, pInterval, pStartPause, pMode, pSpeed

on beginSprite me
pS = sprite (spriteNum)
pInterval = random (3) -- seconds
pStartPause = the ticks
pMode = #wait
pSpeed = random (20) + 5
pS.locV = - pS.height
pS.locH = random (the stageRight - the stageLeft)
end

on exitFrame me
case pMode of
#wait:
if the ticks > pStartPause + pInterval * 60 then
pMode = #falling
end if
#falling:
if pS.top < the stageBottom then
pS.locV = pS.locV + pSpeed
else
pMode = #reset
end if
#reset:
pS.locV = - pS.height
pS.locH = random (the stageRight - the stageLeft)
pMode = #wait
pStartPause = the ticks
end case
end


--
Craig Wollman
Word of Mouth Productions
phone 212 724 8302
fax 212 724 8151
[url]www.wordofmouthpros.com[/url]
"Opyuse" <webforumsuser@macromedia.com> wrote in message
news:bh59af$njg$1@forums.macromedia.com...

> I have to make a game with randomly falling sprites but I can't work out

the lingo to get this to happen.

>
> Any help you can give will be great?
>
> Thank you
>
>
>

[Opyuse webforumsuser@macromedia.com]

Thanks alot thats great

[Opyuse webforumsuser@macromedia.com]

Sorry about this but when I entered the code you gave this error message appeared

Variable used before assigned a value
case pMode of?

How do I get rid of this error?

[Mark A. Boyd]

On 10 Aug 2003, "Opyuse" [email]webforumsuser@macromedia.com[/email] wrote:

> Variable used before assigned a value
> case pMode of?
>
> How do I get rid of this error?

You forgot the line of code that declares the property variables. Put this
at the top of the script (outside of any handlers)

property pS, spriteNum, pInterval, pStartPause, pMode, pSpeed



--
Mark A. Boyd
Keep-On-Learnin' :)

[Word of Mouth Productions]

Thanks Mark

--
Craig Wollman
Word of Mouth Productions
phone 212 724 8302
fax 212 724 8151
[url]www.wordofmouthpros.com[/url]
"Mark A. Boyd" <mblists@sanDotrr.com> wrote in message
news:Xns93D367CFACE5FmblistssanDotrrcom@65.57.83.2 09...

> On 10 Aug 2003, "Opyuse" [email]webforumsuser@macromedia.com[/email] wrote:
>

> > Variable used before assigned a value
> > case pMode of?
> >
> > How do I get rid of this error?

>
> You forgot the line of code that declares the property variables. Put this
> at the top of the script (outside of any handlers)
>
> property pS, spriteNum, pInterval, pStartPause, pMode, pSpeed
>
>
>
> --
> Mark A. Boyd
> Keep-On-Learnin' :)