How can I attach behaviors to a sprite using another behavior

[Listat webforumsuser@macromedia.com]

Hello, Í want to make a behavior to attach other behavior to a sprite, but I don't know how to do it.

Could you help me?

Thanks.

[JB]

Look into the scriptlist and scriptinstancelist properties of sprites,
Ive done it before but it's a hazy memory now.

[Robert Tweed]

"Listat" <webforumsuser@macromedia.com> wrote in message
news:bqj7e3$mm5$1@forums.macromedia.com...

>
> Hello, Í want to make a behavior to attach other behavior to a sprite, but
> I don't know how to do it.

What a coincidence! I've just written a new function to take care of
precisely this job. It emulates the job normally performed by the score, so
you don't need to worry about whether your behaviours will work properly or
not. A tutorial will be coming soon, but using the function is very easy to
use, simply call:

addScriptToSprite( sp, scriptName )

Where sp is either a sprite object or a channel number. The third parameter
is optional, and lets you override the getPropertyDescriptionList defaults
for the behaviour. For instance, if you want to set pProp to something other
than the default specified by getPDL, you would do this:

addScriptToSprite( sp, scriptName, [ #pProp:"use this value" ] )

Heres the code you need:

-- MOVIE SCRIPT: Add a behaviour at runtime.

on addScriptToSprite aSprite, aScriptName, aOverridePDL

-- Make sure we are dealing with a sprite
if( ilk( aSprite, #integer ) ) then
aSprite = sprite( aSprite )
else if( not ilk( aSprite, #sprite ) ) then
return
end if

-- Create the script instance
vScript = script( aScriptName ).rawNew()

-- Add spriteNum and call new()
vScript.setaProp( #spriteNum, aSprite.spriteNum )
call( #new, [vScript] )

-- Get defaults from PDL, if applicable
if( vScript.handler( #getPropertyDescriptionList ) ) then

-- Check PDL override is a list, so we don't get errors
if( not ilk( aOverridePDL, #propList ) )then
aOverridePDL = [:]
end if

-- Get PDL
vPDL = vScript.getPropertyDescriptionList()

-- Get each default from PDL or override list
repeat with i = count( vPDL ) down to 1
vProp = vPDL.getPropAt( i )
if( ilk( vProp, #symbol ) ) then
vValue = aOverridePDL.getaProp( vProp )
if( voidP( vValue ) ) then
vSet = vPDL.getAt( i )
if( ilk( vSet, #propList ) ) then
vValue = vSet.getaProp( #default )
end if
end if
vScript.setaProp( vProp, vValue )
end if
end repeat
end if

-- Add instance to scriptInstanceList
aSprite.scriptInstanceList.add( vScript )

-- Call beginSprite, if applicable
call( #beginSprite, [vScript] )
end
-- END

- Robert