multiple arrays from one text file with one column

[Faz]

Hello

I have a text file in a single column which has name address, phone
age of each people as below

Name
Address
phone
age
Name
Address
phone
age

I want to put all the names in the names array, all the address in
address array all the phone in the phone array etc

Please help

Thanks

[Bob Walton]

Faz wrote:

....

> I have a text file in a single column which has name address, phone
> age of each people as below
>
> Name
> Address
> phone
> age
> Name
> Address
> phone
> age
>
> I want to put all the names in the names array, all the address in
> address array all the phone in the phone array etc

....


An excellent starting point is with the book "Learning Perl". Read
that, and if you then have problems you can't get past, please post here
again.


--
Bob Walton

[John Bokma]

Faz wrote:

> Hello
>
> I have a text file in a single column which has name address, phone
> age of each people as below
>
> Name
> Address
> phone
> age
> Name
> Address
> phone
> age

So all people are called "Name", live at "Address" and their phone
number is p h o n e and their age is age?

> I want to put all the names in the names array, all the address in
> address array all the phone in the phone array etc

my $filename = "textfileinasinglecolumnwhichhasetc.txt";
my $state = 0;

my(@names, @address, @phone, @age);

open(FILE, $filename) or die "Can't open '$filename': $!";
while (my $line = <FILE>) {
chomp($line);

SWITCH: {
$state == 0 && do { push @names, $line; last SWITCH; };
$state == 1 && do { push @address, $line;last SWITCH; };
$state == 2 && do { push @phone, $line; last SWITCH; };
$state == 3 && do { push @age, $line; last SWITCH; };
};
$state++;
$state = 0 if $state == 4;
}
close(FILE) or die "Can't close '$filename': $!";

Not tested.

probably a better way to store data like this would be to use an array
of arrays. Or even better an array of hashes. But I don't know what you
are going to do with it :-).

Notice it doesn't check anything. Normally I would read a line, validate
it and store if it is what I expected and change the state.

I expect much nicer, probably more perlish ways to do it :-)

Note I focussed on readability ;-).

--
Kind regards, feel free to mail: mail(at)johnbokma.com (or reply)
virtual home: [url]http://johnbokma.com/[/url] ICQ: 218175426
John web site hints: [url]http://johnbokma.com/websitedesign/[/url]

[John W. Krahn]

Faz wrote:

>
> I have a text file in a single column which has name address, phone
> age of each people as below
>
> Name
> Address
> phone
> age
> Name
> Address
> phone
> age
>
> I want to put all the names in the names array, all the address in
> address array all the phone in the phone array etc

Why four different arrays? A single array of arrays or array of hashes would make more sense.

A simple example (untested):

open IN, 'text_file' or die "Cannot open text_file: $!";
my ( @names, @addresses, @phones, @ages );
until ( eof IN ) {
chomp( my $temp = <IN> );
push @names, $temp;
chomp( $temp = <IN> );
push @addresses, $temp;
chomp( $temp = <IN> );
push @phones, $temp;
chomp( $temp = <IN> );
push @ages, $temp;
}
close IN;

for my $index ( 0 .. $#names ) {
print "Name: $name[$index]\n";
print "Address: $addresses[$index]\n";
print "Phone: $phones[$index]\n";
print "Age: $ages[$index]\n\n";
}


Or with an array of arrays:

open IN, 'text_file' or die "Cannot open text_file: $!";
my @data;
until ( eof IN ) {
push @data, [ grep chomp, map scalar <IN>, 1 .. 4 ];
}
close IN;

for my $record ( @data ) {
print "Name: $record->[0]\n";
print "Address: $record->[1]\n";
print "Phone: $record->[2]\n";
print "Age: $record->[3]\n\n";
}


Or with an array of hashes:

open IN, 'text_file' or die "Cannot open text_file: $!";
my @data;
my @fields = qw/Name Address Phone Age/;
until ( eof IN ) {
@{ $data[ @data ] }{ @fields } = grep chomp, map scalar <IN>, 1 .. 4;
}
close IN;

for my $record ( @data ) {
for my $field ( @fields ) {
print "$field: $record->{$field}\n";
}
print "\n";
}



John
--
use Perl;
program
fulfillment

[Anno Siegel]

Faz <lfazal@hotmail.com> wrote in comp.lang.perl.misc:

> Hello
>
> I have a text file in a single column which has name address, phone
> age of each people as below
>
> Name
> Address
> phone
> age
> Name
> Address
> phone
> age
>
> I want to put all the names in the names array, all the address in
> address array all the phone in the phone array etc

my ( @names, @address, @phone, @age);
push @{ ( \ ( @names, @address, @phone, @age) )[ $. % 4]}, $_ while <DATA>;

Anno

[dominix]

"Faz" <lfazal@hotmail.com> wrote in message
news:13ddbd75.0309081829.1a6803cc@posting.google.c om...

> Hello
>
> I have a text file in a single column which has name address, phone
> age of each people as below
>
> Name
> Address
> phone
> age
> Name
> Address
> phone
> age
>
> I want to put all the names in the names array, all the address in
> address array all the phone in the phone array etc
>
> Please help
>
> Thanks

OK, I know it's a perl forum, but in that case shouldn't it be faster to use
sed like

cat myfile |sed -e " /.*/{
N
N
N
s/\n/;/g
}"

which produce
Name;Address;phone;age
Name2;Address2;phone2;age2
....


HTH

--
dominix

[Chief Squawtendrawpet]

Anno Siegel wrote:

> my ( @names, @address, @phone, @age);
> push @{ ( \ ( @names, @address, @phone, @age) )[ $. % 4]}, $_ while <DATA>;

Don't you need to use this instead: [($. - 1) % 4]

Otherwise, the items end up in the wrong arrays.

Can anyone help me understand why/how this code works?
\ ( @names, @address, @phone, @age)

Does it produce the same thing as this?
(\@names, \@address, \@phone, \@age)

Chief S.

[Anno Siegel]

Chief Squawtendrawpet <cs@edu.edu> wrote in comp.lang.perl.misc:

> Anno Siegel wrote:

> > my ( @names, @address, @phone, @age);
> > push @{ ( \ ( @names, @address, @phone, @age) )[ $. % 4]}, $_

> while <DATA>;
>
> Don't you need to use this instead: [($. - 1) % 4]
>
> Otherwise, the items end up in the wrong arrays.

Right. Or make it more obscure:

push @{ ( \ ( @age, @names, @address, @phone) )[ $. % 4]}, $_
while <DATA>;

> Can anyone help me understand why/how this code works?
> \ ( @names, @address, @phone, @age)
>
> Does it produce the same thing as this?
> (\@names, \@address, \@phone, \@age)

Yes. It's an obscure feature of the backslash operator, but it has its
uses. See perldoc perlref.

Anno