Resizing document from upper left proxy

[Yoli_Thompson@adobeforums.com]

IDCS - Is there a way to resize a page (document setup) and have it resize from upper left of current dimensions?

If I have an ad layout, 3" x 4" on a letter size page (set up this way to add notes for customer below the ad) and ad it's not perfectly centered. After ad is approved I remove notes and want to make document 3" x 4" for pdf output, so I place the ad at 0X 0Y coordinates, reduce document size but it reduces from the center, not upper left... so I have to reposition it--any tips? Thanks

[Gerald_Singelmann@adobeforums.com]

You could try this script.




tell application "Adobe InDesign CS2"
set aDoc to active document
set crntXSize to page width of document preferences of aDoc
set crntYSize to page height of document preferences of aDoc
set myDialog to make dialog with properties {name:"Seitengröße ändern"}
tell myDialog
make dialog column
tell the result
make static text with properties {static label:"Pagewidth:"}
make static text with properties {static label:"Pageheight:"}
end tell
make dialog column
tell the result
set nuXSizeField to make real editbox with properties {edit value:crntXSize}
set nuYSizeField to make real editbox with properties {edit value:crntYSize}
end tell
end tell
set nu to show myDialog
if nu is true then
set nuXSize to edit value of nuXSizeField
set nuYSize to edit value of nuYSizeField
set moveByX to (crntXSize - nuXSize) / 2
set moveByY to (crntYSize - nuYSize) / 2
-- destroy dialog
else
destroy myDialog
return
end if
set enable layout adjustment of layout adjustment preferences of aDoc to false
set page width of document preferences of aDoc to nuXSize
set page height of document preferences of aDoc to nuYSize

set allPage to every page of aDoc
repeat with aPage in allPage
if side of aPage is right hand then
move every page item of aPage by {0, moveByY}
else if side of aPage is left hand then
move every page item of aPage by {2 * moveByX, moveByY}
else if side of aPage is single sided then
move every page item of aPage by {moveByX, moveByY}
end if
set allGuides to every guide of aPage
repeat with aGuide in allGuides
if orientation of aGuide is horizontal then
set location of aGuide to ((location of aGuide) + moveByY)
else
if side of aPage is right hand then
else if side of aPage is left hand then
set location of aGuide to ((location of aGuide) + (2 * moveByX))
else if side of aPage is single sided then
set location of aGuide to ((location of aGuide) + moveByX)
end if
end if
end repeat
end repeat

set allMSpreads to every master spread of aDoc
repeat with aMSpread in allMSpreads
set allMPages to every page of aMSpread
repeat with aPage in allMPages
if side of aPage is right hand then
move every page item of aPage by {0, moveByY}
else if side of aPage is left hand then
move every page item of aPage by {2 * moveByX, moveByY}
else if side of aPage is single sided then
move every page item of aPage by {moveByX, moveByY}
end if
set allGuides to every guide of aPage
repeat with aGuide in allGuides
if orientation of aGuide is horizontal then
set location of aGuide to ((location of aGuide) + moveByY)
else
if side of aPage is right hand then
else if side of aPage is left hand then
set location of aGuide to ((location of aGuide) + (2 * moveByX))
else if side of aPage is single sided then
set location of aGuide to ((location of aGuide) + moveByX)
end if
end if
end repeat
end repeat
end repeat
end tell




As usual I cannot guarantee that it covers all eventualities, so be sure to save before running it.

Gerald