Slide Show problem

[Dead Parrot webforumsuser@macromedia.com]

Hey everyone. I'm new to the forum and I thought I'd try this question out. It'd be easier to give you the web link (it has my problem).

[url]www.verge.ca/directorquestion[/url]

I hope you can help me out.

[calan@mighty.co.za webforumsuser@macromedia.com]

Being more of a Flash Mx user I'm not sure of director's capability but will try to help.

Load external .dir files which load the images and contain a stop frame to control the main movie. If he uses 13 images that week, he only includes .dir files 1-13. When the .dir is not there the orginal movie will not stop.

Not great but I don't know lingo - you might want to wait for someone more lingo literate.

P.S. If you're online, please take a look at my posting for launching an external .exe - the 'open' command gives me an error and not sure what I'm screwing up.

Later.

[paul]

Hey, this may be too late, but i found this in the help files... It
essentially creates a list out of all the files in a particular folder. With
that list you can set up a presentation that plays ANY file no matter what
name it has, and you can even count the number of files in the folder, which
seems to answer your question to some extent...

on ListFiles thePath
fileList = [ ]

repeat with i = 1 to 100

n = getNthFileNameInFolder(thePath, i)

if n = EMPTY then exit repeat

fileList.append(n)

end repeat

return fileList

end currentFolder



"Dead Parrot" <webforumsuser@macromedia.com> wrote in message
news:bqe9qn$4d2$1@forums.macromedia.com...

> Hey everyone. I'm new to the forum and I thought I'd try this question

out. It'd be easier to give you the web link (it has my problem).

>
> [url]www.verge.ca/directorquestion[/url]
>
> I hope you can help me out.
>
>
>

[Dead Parrot webforumsuser@macromedia.com]

Thanks for the responses guys. I do believe that Paul is on the right track...and what I hadn't realized is that the way I'm doing it wouldn't work (what if the person decided to put a .txt file instead of a .jpeg one day.....the Projector would look for a jpeg).

Unfortunately....my Lingo skills are very basic. I've been using it since version 4.0 but I mainly use it for navigation and that's it. So when variables and listFiles and these things come up, I'm completely lost. Sorry.....I might have to seek some other way of obtaining this.

[JPrice]

I trap for the extension so that I know if the file is an image (*.jpg) or
if it's some bit of text that is associated with that image (*.txt). These
handlers are in a movie script.

global gImageFolder -- where the images are located
global gImageList -- a list of all image file names
global gImageNum -- the number of the current image

-- this handler looks at each file in the folder and gets the filename of
that image
on getImageList
gImageList = []
repeat with i = 1 to 255
filename = getNthFileNameinFolder(gImageFolder,i)
ext=filename.char[filename.char.count-2..filename.char.count]
if filename = "" then exit repeat
if ext="jpg" then -- this just gets image filenames
add gImageList, filename
end if
end repeat
sort gImageList
end


-- this handler resets the filename of the image to a new file
on showImage
sprite(1).visible=false -- my image is in channel 1
mem=member("image")
mem.filename = gImageFolder & gImageList[gImageNum]
mem.regpoint=point(mem.width/2, mem.height/2)

if mem.width< mem.height then
imagetype="portrait"
-- put image on right side; locations are based on the size of my stage
sprite(1).loc=point((740-mem.width/2), mem.height/2)
set member("fileNameText").width= 700 - mem.width
sprite(6).loc=point(30,60) -- a text member is in channel 6
else
imagetype="Landscape"
-- center image
loffset=(760-mem.width)/2
sprite(1).loc=point(loffset+mem.width/2,mem.height/2)
set member("fileNameText").width=625
sprite(6).loc=point(130, mem.height + 10)
end if
sprite(1).visible=true

-- get text for image
fileObj=new(Xtra "FileIO")
x=gImageList[gimageNum]
filename=gImageFolder & x.char[1..(x.length-4)]&".txt"
Result = baFileExists( FileName )
if result=1 then
openfile(fileObj, filename,1)
member("fileNameText").text=readfile(fileObj)
closefile(fileObj)
else
member("fileNameText").text=""
end if

if imagetype="landscape" then
sprite(6).member.fontstyle=[#bold]
sprite(6).member.fontsize=15
else
sprite(6).member.fontsize=18
sprite(6).member.fontstyle=[#plain]
end if
end

on nextImage
gImageNum = gImageNum + 1
if gImageNum > gImageList.count then
alert "This is the last picture."
else
showImage
end if
end

on previousImage
gImageNum = gImageNum - 1
if gImageNum < 1 then
alert "This is the first picture."
else
showImage
end if
end

On my image, I had this behavior:

global gImageFolder -- where the images are located
global gImageList -- a list of all image file names
global gImageNum -- the number of the current image

property subfolder

on beginsprite
-- determine the location of the images
gImageFolder = the moviepath & subfolder
-- set other globals
getImageList -- this will have a list of just the images.
gImageNum = 1
-- show first image
showImage
end

on getPropertyDescriptionList
list = [:]
addProp list, #subfolder, [#comment: "Subfolder", #format:
#string,#default: "Images\"]
return list
end getPropertyDescriptionList

On my buttons, I had the calls for the nextimage or previousimage handlers.

You have to have fileIO in your xtras folder.

HTH,
Judy


"Dead Parrot" <webforumsuser@macromedia.com> wrote in message
news:bqh2ek$rnn$1@forums.macromedia.com...

> Thanks for the responses guys. I do believe that Paul is on the right

track...and what I hadn't realized is that the way I'm doing it wouldn't
work (what if the person decided to put a .txt file instead of a .jpeg one
day.....the Projector would look for a jpeg).

>
> Unfortunately....my Lingo skills are very basic. I've been using it since

version 4.0 but I mainly use it for navigation and that's it. So when
variables and listFiles and these things come up, I'm completely lost.
Sorry.....I might have to seek some other way of obtaining this.

>
>